Hvordan kan jeg pause et skript?

[Dryper]

Heisann jeg har nå stressa med å lage en autoclicker (faktisk ganske lett) men har støtt på et problem..

 

 

Jeg trenger et eller annet som kan pause klikkingen.. ville vært best med feks om du trykker F1 så Pause/Starter autoclickeren igjen.. dette er den koden jeg har skrevet til nå

 

Module Module1
Public Declare Auto Function SetCursorPos Lib "User32.dll" (ByVal X As Integer, ByVal Y As Integer) As Long
Public Declare Sub mouse_event Lib "user32" Alias "mouse_event" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Public Const MOUSEEVENTF_LEFTDOWN = &H2 ' left button down
Public Const MOUSEEVENTF_LEFTUP = &H4 ' left button up
Sub Main()
	While (2 + 2 = 4)
		System.Threading.Thread.Sleep(100)
		mouse_event(MOUSEEVENTF_LEFTDOWN, 0, 0, 0, 0)
		mouse_event(MOUSEEVENTF_LEFTUP, 0, 0, 0, 0)
	End While
End Sub

End Module

 

Takker for all hjelp !

[aadnk]

Regner med du kan gjøre noe som følger:

Module Module1

   Declare Auto Function GetKeyState Lib "user32" (ByVal nVirtKey As Integer) As UInteger
   Declare Auto Function SetCursorPos Lib "User32.dll" (ByVal X As Integer, ByVal Y As Integer) As Integer
   Declare Sub mouse_event Lib "user32" Alias "mouse_event" (ByVal dwFlags As Integer, ByVal dx As Integer, _
    ByVal dy As Integer, ByVal cButtons As Integer, ByVal dwExtraInfo As Integer)

   Public Const MOUSEEVENTF_LEFTDOWN = &H2
   Public Const MOUSEEVENTF_LEFTUP = &H4

   Private Function KeyPressed(ByVal Key As ConsoleKey) As Boolean
       ' Hent ut den første (høyeste) biten
       Return GetKeyState(Key) And &HF0000000
   End Function

   Sub Main()

       Dim Pressed As Boolean, Last As Boolean, Pause As Boolean

       Do Until KeyPressed(ConsoleKey.Escape)

           Do
               ' Hent pauseknappens status
               Pressed = KeyPressed(ConsoleKey.Pause)

               ' Reverser posisjon når knappen er ferdig nedtrykket
               If Pressed <> Last Then
                   If Not Pressed Then Pause = Not Pause
                   Last = Pressed
               End If

               System.Threading.Thread.Sleep(10)
           Loop While Pause

           System.Threading.Thread.Sleep(100)
           mouse_event(MOUSEEVENTF_LEFTDOWN, 0, 0, 0, 0)
           mouse_event(MOUSEEVENTF_LEFTUP, 0, 0, 0, 0)
       Loop
   End Sub

End Module