Hjelp med diverse ting til en " litt " mer avansert web broswer

[GeirGrusom]

Du må lukke filen når funksjonen er ferdig.

 

hvis du bare bruker StreamReader, kan du bruke using

 

Using reader As StreamReader = New StreamReader("minfil.txt")

 ' Les les les les....
End Using

 

... tror det er sånn Using brukes i VB.NET, er ikke sikker egentlig.

[Gjest]

Du må lukke filen når funksjonen er ferdig.

 

hvis du bare bruker StreamReader, kan du bruke using

 

Using reader As StreamReader = New StreamReader("minfil.txt")

 ' Les les les les....
End Using

 

... tror det er sånn Using brukes i VB.NET, er ikke sikker egentlig.

 

Så litt på det med StreamReader, nyttig men hvordan kan jeg bruke den til og overskrive en tekst som allerede står i min tekstfil ? så altså, vis jeg skriver inn noe nytt i den textboxen så skal den fjerne det gammle som står der i tekstfila.

 

Denne kommer nok til og bli brukt i min " favoritter " meny, men hvordan får jeg brukt den kommandoen som er slik " leser en spesifikt linje i teksten ? " hva må jeg bruke i forhold til favoritten med tanke på legg til og delete ?

 

TAKK !

[Manfred]

System.IO.File.Delete(path);

 

uansett så overskriver vel StremWriter så lenge du ikke initierer den med StreamWriter(path, true), da andre parameter er vel bool append, om jeg ikke husker helt feil.

[fenhopi]

Angående historie og favoritter går det vell ann og bruke my.string? og Items.add?

[Gjest]

Hei folkens

 

Så litt på denne nettleseren: LINK

En clone av IE 7.

Den var litt kul med tanke på tabs, favorites, history fra gang til gang osv !

hadde vært gøy om noen kunne titt nærmere en det jeg gjorde og funnet ut hvordan jeg lager det slik ? Og evnt, andre kan benytte seg av det

 

 

Vedlegg:

Source koden av programmet jeg har linka fordi som ikke gidder og registrere seg der.

 

edit:

glemte vedlegg...

Endret 1. mars 2008 av Gjest

[Manfred]

Hvorfor kan du ikke ta deg en titt selv? hvorfor skal vi sitte og gjøre jobben for deg?

[Gjest]

Hvorfor kan du ikke ta deg en titt selv? hvorfor skal vi sitte og gjøre jobben for deg?

 

Har gjort det og nærmer meg ferdig

[fenhopi]

Hvorfor kan du ikke ta deg en titt selv? hvorfor skal vi sitte og gjøre jobben for deg?

 

Har gjort det og nærmer meg ferdig

 

Eak, har du funnet ut av favorites? Vist du har det hadde du gidded å poste koden så eg kan ta ein titt?

[Gjest]

Hvorfor kan du ikke ta deg en titt selv? hvorfor skal vi sitte og gjøre jobben for deg?

 

Har gjort det og nærmer meg ferdig

 

Eak, har du funnet ut av favorites? Vist du har det hadde du gidded å poste koden så eg kan ta ein titt?

 

Hei !

Jeg vet ikke helt jeg ass, men jeg har funnet ut noe om koden:

Klikk for å se/fjerne innholdet nedenfor

Favorites Loading Code

Klikk for å se/fjerne innholdet nedenfor

'Favorites Loading Code 

'In most custom browser implementations you will probably want to 
'have your own favorite storage information, storing fav icons in your own cache
'or in a database. You may also want to implement a custom import / export wizard. 
'Since favorites are just text files simular to .ini files, for this example
'we'll just load them the quickest way by loading the path and during the 
'onclick in the handler open the file and direct the browser to the url. 

Private Sub LoadFavorites()
	Dim Path As String = Environment.GetFolderPath(Environment.SpecialFolder.Favorites)
	tvFavs.BeginUpdate()
	' Clear the Favorites list
	tvFavs.Nodes.Clear()
	' Load favorites from all sub-directories
	LoadFolders(New System.IO.DirectoryInfo(Path), Nothing, Nothing)
	' Load the favorites from the favorites folder
	LoadPath(Path, Nothing, Nothing)
	'Now lets load the links toobar
	LoadLinkFolders(New System.IO.DirectoryInfo(Path & "\Links\"), Nothing)
	LoadLinksPath(Path & "\Links\", Nothing)
	' Repaint the TreeView
	tvFavs.EndUpdate()
End Sub

Private Sub LoadFolders(ByVal dirInfo As System.IO.DirectoryInfo, _
ByVal currentNode As TreeNode, ByVal oitm As ToolStripMenuItem)

	Dim objNode As System.Windows.Forms.TreeNode
	Dim fitm As ToolStripMenuItem

	Dim objDir As System.IO.DirectoryInfo

	For Each objDir In dirInfo.GetDirectories()
		If currentNode Is Nothing Then
			objNode = tvFavs.Nodes.Add(objDir.Name, objDir.Name, 0, 1)
			objNode.Tag = String.Empty
			fitm = mnuFavs.DropDownItems.Add(objDir.Name)
			fitm.Image = My.Resources.folder3
		Else
			objNode = currentNode.Nodes.Add(objDir.Name, objDir.Name, 0, 1)
			objNode.Tag = String.Empty
			fitm = oitm.DropDownItems.Add(objDir.Name)
			fitm.Image = My.Resources.folder3
		End If
		' Set the full path of the folder
		objNode.Tag = objDir.FullName
		fitm.Tag = objDir.FullName

		If objDir.GetDirectories().Length = 0 Then
			' This node has no further sub-directories
			LoadPath(objDir.FullName, objNode, fitm)
		Else
			' Add this folder to the current node and continue
			' processing sub-directories.
			LoadFolders(objDir, objNode, fitm)
			LoadPath(objDir.FullName, objNode, fitm)
		End If
	Next objDir
End Sub

Private Sub LoadPath(ByVal strPath As String, _
ByVal currentNode As TreeNode, ByVal mitm As ToolStripMenuItem)

	Dim oNode As TreeNode
	Dim oitm As ToolStripMenuItem
	Dim name As String
	Dim objDir As New System.IO.DirectoryInfo(strPath)
	Dim SmallIco As IntPtr
	Dim shinfo As SHFILEINFO
	shinfo = New SHFILEINFO
	' Process each File in the path with a ".url" extension
	Dim objFile As System.IO.FileInfo
	For Each objFile In objDir.GetFiles("*.url")
		oNode = New TreeNode
		oitm = New ToolStripMenuItem
		'///////////////////////////////////////////////////
		'get the icon.
		'Note:
		'Here you could call the appmanager code to get the actual 
		'favorite icon from the site (will slow things down)...
		'If you decide to implement your own custom favorites
		'grab the fav icon and store it in an access db, xml file etc
		'either by path or ole object and save it locally.
		shinfo.szDisplayName = New String(Chr(0), 260)
		shinfo.szTypeName = New String(Chr(0), 80)
		'Get the small icon.
		SmallIco = SHGetFileInfo(objFile.FullName, 0, shinfo, _
					Marshal.SizeOf(shinfo), _
					SHGFI_ICON Or SHGFI_SMALLICON)
		'////////////////////////////////////////////////////
		' Set the Text property to the "Friendly" name
		name = Path.GetFileNameWithoutExtension(objFile.Name)
		Dim oIcon As Icon = System.Drawing.Icon.FromHandle(shinfo.hIcon)
		tvFavs.ImageList.Images.Add(name, oIcon.ToBitmap)
		oNode.Text = name
		oNode.Tag = objFile.FullName
		oNode.ImageKey = name
		oNode.SelectedImageKey = name
		If currentNode Is Nothing Then
			tvFavs.Nodes.Add(oNode)
			oitm.Text = name
			oitm.Image = oIcon.ToBitmap
			oitm.Tag = objFile.FullName
			mnuFavs.DropDownItems.Add(oitm)
			AddHandler oitm.Click, AddressOf HandleFav
			'AddHandler oitm.MouseDown, AddressOf HandleFavMouseDown
		Else
			currentNode.Nodes.Add(oNode)
			oitm.Text = name
			oitm.Image = oIcon.ToBitmap
			oitm.Tag = objFile.FullName
			mitm.DropDownItems.Add(oitm)
			AddHandler oitm.Click, AddressOf HandleFav
			'AddHandler oitm.MouseDown, AddressOf HandleFavMouseDown
		End If
	Next objFile
End Sub


Private Sub LoadLinkFolders(ByVal dirInfo As System.IO.DirectoryInfo, _
ByVal oitm As ToolStripMenuItem)

	Dim fitm As ToolStripMenuItem
	Dim objDir As System.IO.DirectoryInfo

	For Each objDir In dirInfo.GetDirectories()
		fitm = New ToolStripMenuItem
		fitm.Text = objDir.Name
		fitm.Tag = ""
		fitm.Image = My.Resources.folder3
		If oitm Is Nothing Then
			tbLinks.Items.Add(fitm)
		Else
			fitm.Image = My.Resources.folder3
			oitm.DropDownItems.Add(fitm)
		End If

		If objDir.GetDirectories().Length = 0 Then
			' This node has no further sub-directories
			LoadLinksPath(objDir.FullName, fitm)
		Else
			' Add this folder to the current node and continue
			' processing sub-directories.
			LoadLinkFolders(objDir, fitm)
			LoadLinksPath(objDir.FullName, fitm)
		End If
	Next objDir
End Sub

Private Sub LoadLinksPath(ByVal strPath As String, _
ByVal mitm As ToolStripMenuItem)

	Dim oitm As ToolStripMenuItem
	Dim name As String
	Dim objDir As New System.IO.DirectoryInfo(strPath)
	Dim SmallIco As IntPtr
	Dim shinfo As SHFILEINFO
	shinfo = New SHFILEINFO
	' Process each URL in the path (URL files end with a ".url" extension
	Dim objFile As System.IO.FileInfo
	For Each objFile In objDir.GetFiles("*.url")
		oitm = New ToolStripMenuItem
		'get the icon.
		shinfo.szDisplayName = New String(Chr(0), 260)
		shinfo.szTypeName = New String(Chr(0), 80)
		'Get the small icon.
		SmallIco = SHGetFileInfo(objFile.FullName, 0, shinfo, _
					Marshal.SizeOf(shinfo), _
					SHGFI_ICON Or SHGFI_SMALLICON)
		' Set the Text property to the "Friendly" name
		name = Path.GetFileNameWithoutExtension(objFile.Name)
		Dim oIcon As Icon = System.Drawing.Icon.FromHandle(shinfo.hIcon)

		If mitm Is Nothing Then
			oitm.Text = name
			oitm.Image = oIcon.ToBitmap
			oitm.Tag = objFile.FullName
			tbLinks.Items.Add(oitm)
			'AddHandler oitm.Click, AddressOf HandleFav
			AddHandler oitm.MouseDown, AddressOf HandleFavMouseDown
		Else
			oitm.Text = name
			oitm.Image = oIcon.ToBitmap
			oitm.Tag = objFile.FullName
			mitm.DropDownItems.Add(oitm)
			'AddHandler oitm.Click, AddressOf HandleFav
			AddHandler oitm.MouseDown, AddressOf HandleFavMouseDown
		End If
	Next objFile
End Sub

Favorite Event Handlers

Klikk for å se/fjerne innholdet nedenfor

' Favorite Event Handlers 

Private Sub HandleFavMouseDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs)
	Select Case e.Button
		Case Windows.Forms.MouseButtons.Left
			Dim fi As ToolStripMenuItem = sender
			Dim obj As New tlxIni(fi.Tag)
			AppManager.CurrentBrowser.Navigate(obj.GetString("INTERNETSHORTCUT", "URL", String.Empty))
		Case Windows.Forms.MouseButtons.Right
			cmFavs.Show(Cursor.Position.X, Cursor.Position.Y)
			fitm = sender
	End Select
End Sub

Private Sub HandleFav(ByVal sender As System.Object, ByVal e As System.EventArgs)

	Dim fi As ToolStripMenuItem = sender
	Dim obj As New tlxIni(fi.Tag)
	AppManager.CurrentBrowser.Navigate(obj.GetString("INTERNETSHORTCUT", "URL", String.Empty))
End Sub

Private Sub tvFavs_NodeMouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.TreeNodeMouseClickEventArgs) Handles tvFavs.NodeMouseClick
	If e.Node.Nodes.Count > 0 Then
		e.Node.Expand()
	Else
		If e.Node.ImageIndex = 0 Then
			Exit Sub
		Else
			Dim obj As New tlxIni(e.Node.Tag)
			AppManager.CurrentBrowser.Navigate(obj.GetString("INTERNETSHORTCUT", "URL", String.Empty))
			gbFavs.Visible = False
		End If
	End If
End Sub

 

Fant mer og - add to favorites

Klikk for å se/fjerne innholdet nedenfor

Private Sub mnuAddFav2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles mnuAddFav2.Click
	AppManager.CurrentBrowser.AddToFavorites("", "")
End Sub

Private Sub AddToFavoritesToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles AddToFavoritesToolStripMenuItem.Click
	AppManager.CurrentBrowser.AddToFavorites(AppManager.CurrentBrowser.Url.ToString, AppManager.CurrentBrowser.DocumentTitle)
End Sub

Private Sub OrganizeFavoritesToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles OrganizeFavoritesToolStripMenuItem.Click
	AppManager.CurrentBrowser.ShowOrganizeFavorites()
End Sub

 

VELDIG mye koding her men du får prøve selv og forrstå koden osv. Har ikke begynnt selv, men last ned programmet ut du og åpne den i VB 2005 / 2008 fordi jeg vil tro at han har mere en det av koden i en annen form eller class file eller noe lingende. IKKE SIKKER !

Så vis du klarer finne svaret hvordan du lager det, post gjerne ?

 

Det var det jeg kunne hjelpe deg siden jeg ikke har funnet det selv.

 

Men nærmer meg snart ferdig her

 

EDIT:

- add to favorites koden ?

Endret 4. mars 2008 av Gjest