Få en liste over filer > ListBox

[Gjest Slettet-aNZFa3]

Her er koden min:

 

Public Class Form1

    Public Musikk As Array = IO.Directory.GetFiles("Musikk\")

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        MusikkShow.Items.Add(Musikk)

    End Sub

End Class

, men alt jeg får opp i ListBox'n er "String[] Array Endret 26. august 2007 av Slettet-aNZFa3

[Gjest Slettet-aNZFa3]

Jeg fant det ut:

 

Public Class Form1

 

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        For Each foundFile As String In IO.Directory.GetFiles("Musikk\")

            MusikkShow.Items.Add(foundFile)

        Next

    End Sub

End Class

 

 

EDIT: men i ListBox'en så kommer det "Musikk\Iron Maiden - 666 Number of the beast.mp3", jeg vil at det bare skal komme "Iron Maiden - 666 Number of the beast"

 

EDIT2: jeg har enda et problem. Jeg får ikke stoppa. eller pausa musikken:

 

Public Class Form1

 

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        For Each foundFile As String In IO.Directory.GetFiles("Musikk")

            MusikkShow.Items.Add(foundFile)

        Next

    End Sub

 

    Private Sub btPlay_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btPlay.Click

        Microsoft.DirectX.AudioVideoPlayback.Audio.FromFile(MusikkShow.SelectedItem).Play()

    End Sub

 

    Private Sub btPause_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btPause.Click

        Microsoft.DirectX.AudioVideoPlayback.Audio.FromFile(MusikkShow.SelectedItem).Pause()

    End Sub

 

    Private Sub btStop_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btStop.Click

        Microsoft.DirectX.AudioVideoPlayback.Audio.FromFile(MusikkShow.SelectedItem).Stop()

    End Sub

End Class

Endret 26. august 2007 av Slettet-aNZFa3

[aadnk]

Noe som følgende, muligens?

Klikk for å se/fjerne innholdet nedenfor

Imports Microsoft.DirectX.AudioVideoPlayback

 

Public Class frmPlayer

 

    ' Holder styr på filstiene

    Public Files() As String

    Public AudioPlayer As Audio ' Avspiller

    Public CurrentFile As Integer = -1

 

    Private Sub frmPlayer_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

 

        Files = IO.Directory.GetFiles("K:\Mp3\Techno\")

 

        ' Legg kun til filnavn

        For Each File As String In Files

            lstFiles.Items.Add(IO.Path.GetFileName(File))

        Next

 

    End Sub

 

    Private Sub frmPlayer_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing

 

        ' Ja, AudioVideoPlayback kan lekke minne!

        Cleanup()

 

    End Sub

 

    Public Sub Cleanup()

 

        ' Rydd opp

        If AudioPlayer IsNot Nothing Then

            AudioPlayer.Stop()

            AudioPlayer.Dispose()

            AudioPlayer = Nothing

        End If

 

    End Sub

 

    Public Function Open(ByVal FileIndex As Integer) As Boolean

 

        Try

            ' Initializer lydobjekt

            Cleanup() : AudioPlayer = New Audio(Files(FileIndex))

        Catch ex As Exception

            ' Evt. vis feilmelding her

        Finally

            ' Lagre filindeks

            CurrentFile = lstFiles.SelectedIndex

            Return True

        End Try

 

    End Function

 

    Private Sub btnPlay_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPlay.Click

 

        ' Se om vi har endret seleksjonen

        If CurrentFile <> lstFiles.SelectedIndex Then

            If lstFiles.SelectedIndex >= 0 AndAlso lstFiles.SelectedIndex < Files.Length Then

                If Open(lstFiles.SelectedIndex) Then

                    AudioPlayer.Play()

                    btnPause.Enabled = True

                    btnStop.Enabled = True

                End If

            End If

        Else

            AudioPlayer.Play()

        End If

 

    End Sub

 

    Private Sub btnPause_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPause.Click

        If AudioPlayer IsNot Nothing Then

            AudioPlayer.Pause()

        End If

    End Sub

 

    Private Sub btnStop_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnStop.Click

        If AudioPlayer IsNot Nothing Then

            AudioPlayer.Stop()

        End If

    End Sub

End Class

Endret 26. august 2007 av aadnk

[Gjest Slettet-aNZFa3]

Tusen takk! Det funka