ASP: Application-objektet i ASP

[Create-IT]

Heisann!

 

Skal lage en website med noen få sider der innholdet kun skal endres av en med admin-rettigheter. Siten skal ha flere språk.

 

Kan det være greit å bruke Application-objektet til å lagre en del av teksten (menytekst, titler og annet innhold på de forskjellige språkene)? Jeg tenker på i stedenfor å kople til en database hver gang sidene blir besøkt. Hva er mest krevende for serveren?

 

Og så et annet spørsmål: Er det mulig å legge inn Array i et application-objekt?

 

 

Setter stor pris på hjelp og synspunkter.

Endret 22. juni 2004 av Create-IT

[aadnk]

Jeg vil nå tro at det er mye raskere å bruke Application objektet for data som hentes fram ofte, enn å bruke databasen. Hvis jeg ikke tar feil lagrer Application objektet sine variabler i RAM'en, noe som naturligvis er raskere enn harddisken (om da det ikke er virtuelt minne vi snakker om).

 

Men over til spørsmålet ditt: Ja, det er mulig å legge en Array inn i Application objektet, men det er ikke mulig å endre noen av elementene i Arrayen direkte. Følgende kode vil derfor gi en feilmelding:

 

<% Application("StoredArray")(3) = "ny verdi" %>

 

For å endre på Arrayen må du derfor lage en kopi av den, som du så setter tilbake til orginalen.

 

---file1.asp---
<%
'Creating and initializing the array.
dim MyArray()
Redim MyArray(5)
MyArray(0) = "hello"
MyArray(1) = "some other string"

'Storing the array in the Application object.
Application.Lock
Application("StoredArray") = MyArray
Application.Unlock

Server.Transfer("file2.asp")
%>

---file2.asp---
<%
'Retrieving the array from the Application Object
'and modifying its second element.
LocalArray = Application("StoredArray")
LocalArray(1) = " there"

'Printing out the string "hello there."
Response.Write(LocalArray(0)&LocalArray(1))

'Re-storing the array in the Application object.
'This overwrites the values in StoredArray with the new values.
Application.Lock
Application("StoredArray") = LocalArray
Application.Unlock
%>

 

Kilde: Microsoft.com

Endret 24. juni 2004 av aadnk

[Create-IT]

Tusen takk aadnk!

 

Setter kjempepris på det.