Form1 altid øverst

[danfredr]

Hei. Er det noen som vet hvordan man får Form1 altid øverst.

Dette er i VB6

 

kan du også skrive koden får at den skal være over startmenyen også ? (Hvis det er mulig)

 

og Hvordan man får FKS form1 transparant (gjennomsiktig) ?

 

takker får svar på fårhond

[aadnk]

For at en form alltid skal være øverst bruker du denne koden som også får vinduet til å komme over startmenyen:

 

Private Declare Sub SetWindowPos Lib "User32" (ByVal hWnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long)

Const HWND_TOPMOST = -1
Const HWND_NOTOPMOST = -2
Const SWP_NOSIZE = &H1
Const SWP_NOMOVE = &H2
Const SWP_NOACTIVATE = &H10
Const SWP_SHOWWINDOW = &H40

Private Sub Form_Activate()

SetWindowPos Me.hWnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE Or SWP_SHOWWINDOW Or SWP_NOMOVE Or SWP_NOSIZE

End Sub

 

Når det gjelder transparente vinduer kan du støte på et problem, denne koden her

vil desverre bare virke på Windows 2000 eller senere. Likevel, koden virker iallefall og mesteparten av windowsbrukerene vil kunne bruke koden:

 

Legg merke til tallet 128. Dette er gjennomsiktighetskonstanten som angir hvor gjennomsiktig vinduet blir. 0 blir usynlig og 255 er ingen gjennomsiktighet.

 

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" (ByVal hWnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long

Const LWA_COLORKEY = &H1
Const LWA_ALPHA = &H2
Const GWL_EXSTYLE = (-20)
Const WS_EX_LAYERED = &H80000

Private Sub Form_Load()

Dim Ret As Long

Ret = GetWindowLong(Me.hWnd, GWL_EXSTYLE)
Ret = Ret Or WS_EX_LAYERED
SetWindowLong Me.hWnd, GWL_EXSTYLE, Ret
SetLayeredWindowAttributes Me.hWnd, 0, 128, LWA_ALPHA

End Sub

Endret 30. november 2003 av aadnk

[danfredr]

tusen takk