Importere data Calc/Excel

[Snickers-is]

Jeg ønsker å lage et ferdig regneark med beregninger som baserer seg på diverse input-data. Jeg har behov for å importere data fra txt-filer som eksporters fra et annet program. Jeg ønsker en måte å kunne trykke på en knapp, browse etter filen, velge den og klikke "ok" eller noe for å få dataene til å lastes automatisk inn på ønsket plass i regnearket.

 

Men hvordan? Jeg har bare funnet diverse muligheter for å linke til eksterne filer eller å sette inn et nytt regneark med disse dataene.

 

 

 

 

Om det er noen som er gode på excel/calc, og har lyst til å være med på å lage et ganske kult simuleringsverktøy tilknyttet høyttalerteknologi så ta gjerne kontakt!

[Harald Staff]

Hei

 

Hvis jeg forstår oppgaven. Excelmakro for Windows dette:

Sub JobbForSvarte()
Dim Fil As Variant
Dim Startcelle As Range
Dim Trg As Worksheet
Dim Rwrite As Long, Cwrite As Long
Fil = Application _
 .GetOpenFilename("Text Files (*.txt), *.txt", , "Fil som skal leses inn:")
If Fil = False Then Exit Sub
On Error Resume Next
Set Startcelle = Application.InputBox("Velg øverste celle vi skal skrive i:", "Inndata", Type:=8)
If Startcelle Is Nothing Then Exit Sub
On Error GoTo 0
Set Trg = Startcelle.Parent
Rwrite = Startcelle(1).Row
Cwrite = Startcelle(1).Column
Call LastInnGreiene(Trg, CStr(Fil), Rwrite, Cwrite)
End Sub

Sub LastInnGreiene(Trg As Worksheet, _
    TekstfilNavn As String, _
    Rwrite As Long, Cwrite As Long)
Dim Linje As String
Dim iFnum As Integer
If Dir(TekstfilNavn) = "" Then Exit Sub
iFnum = FreeFile
Open TekstfilNavn For Input As #iFnum
While Not EOF(iFnum)
    Line Input #iFnum, Linje
    Trg.Cells(Rwrite, Cwrite).Value = Trim(Linje)
    Rwrite = Rwrite + 1
Wend
Close #iFnum
End Sub

Så kan det være at tekstfilen din bruker tab-separator e.l. for kolonneskille, punktum som desimalseparator, ... Hvis dette er et større og komplisert prosjekt foreslår jeg at du kontakter Ketil hos http://www.excelguru.no/. Flink mann.

 

Beste hilsen Harald

[Snickers-is]

Ja, det er en tabell med tab-separator og punktum som kommaseparator.

 

Hvor kan koden legges inn? Hva gjør den?

[Harald Staff]

Den gjør det du ba om. Koden legges i VBA-editoren (Alt F11 eller tilsvarende) i en modul (meny Insert > Module).

 

Beste hilsen Harald

[Snickers-is]

Takker for det Harald!

Jeg tror jeg får litt hjelp av en annen kar for å få denne koden inn på riktig måte. Jeg har aldri mekket makroer, eller laget noe som har med VBA å gjøre, men skal ikke se bort fra at dette ordner seg til slutt.