[Løst] Hjelp til formel i excel (2010) (ANTALL.HVIS)

[geror]

Jeg har behov for å føre en oversikt i et excelskjema (2010) som kan telle avvik (nå ført i B3) dersom det etter en nærmere satt frist ikke er tatt kontakt med kunde. Denne fristen står nå i E-kolonnen.

 

Dagens formel i B3 er som følger; =ANTALL.HVIS(E7:E6934;"<"&IDAG())

 

Når fristen for kontakt overskrider dagens dato, telles altså avviket i B3. Problemet er bare det at når det tas kontakt med kunde innen fristen (dette føres i F-kolonnen), så vil formelen medføre at avviket like fullt telles i B3.

 

Formelen jeg trenger hjelp til må altså gi følgende resultat: Dersom fristen i E-kolonnen (eks E7) overskrider dagens dato skal det telles avvik i B3, men IKKE hvis dato for kontakt med kunden i F-kolonnen (eks F7) er tidligere eller lik fristdatoen som er satt i E.

 

Eks

 

Frist for kontakt Utført

02.01.14 (E7) 20.12.2013 (F7)

 

I dette tilfellet må altså formelen føre til at det IKKE telles avvik i B3, da kontakt med kunden ble gjort før fristen den 2.1.14.

 

På forhånd takk!

[Harald Staff]

Hei

 

Hvis jeg forstår deg rett:

 

=ANTALL.HVIS(E7:E6934;">"&IDAG())-SUMMERPRODUKT((F7:F6934<=E7:E6934)*1)

 

Siste ledd er en matriseformel, så det er mulig du merker at den trenger litt tid på 7000 rader.

 

Beste hilsen Harald

[geror]

Det funket som bare det, og var helt korrekt forstått. Men en liten sak bare. Når jeg nå legger inn denne formelen så teller den minus på de som er utført innen fristen. Når jeg nå har avvik på 5 og korrekt på 50 står det dermed -45 i B3 istedet for at det står 5 der. Har du et forslag som gjør at det KUN telles ved avvik?

 

Tusen takk for hjelpen!

[Harald Staff]

Au da. Jeg har surret med ">" og "<". Det skal være "<" som er "før i dag".

 

Men det er grenseverdier ute og går ser jeg. Lurer på om du blir kvitt de fleste med Størtst:

 

=STØRST(ANTALL.HVIS(E7:E6934;"<"&IDAG())-SUMMERPRODUKT((F7:F6934<=E7:E6934)*1);0)

 

Harald

[geror]

Jeg er helt imponert at det går an å kunne dette her..

 

Hvis jeg legger inn formelen =STØRST(ANTALL.HVIS(E7:E6934;"<"&IDAG())-SUMMERPRODUKT((F7:F6934<=E7:E6934)*1);0) så får jeg resultat på 0, så dette funket ikke.

 

Når jeg endrer til =ANTALL.HVIS(E7:E6934;"<"&IDAG())-SUMMERPRODUKT((F7:F6934<=E7:E6934)*1)

altså klammen, så blir resultatet mindre i minus, men fremdeles telles det minus.

[geror]

Beklager.

 

Resultatet ved =STØRST(ANTALL.HVIS(E7:E6934;"<"&IDAG())-SUMMERPRODUKT((F7:F6934<=E7:E6934)*1);0) ble 1.

[Harald Staff]

Hm, jeg ser at det blir trøbbel med tomme celler (som Excel oppfatter som 31.12.1899 i datoregning) både i E og F. Det kompliserer såpass at jeg ikke løser denne innen fredagspilsen. Regnestykket får surre i bakhodet på egenhånd en stund

 

Beste hilsen Harald

[Harald Staff]

Hei igjen

 

Jeg tror det må bli sånn:

 

=SUMMERPRODUKT((E7:E7000<IDAG())*(E7:E7000>0)*(F7:F7000<1))+SUMMERPRODUKT((E7:E7000<IDAG())*(E7:E7000>0)*(F7:F7000>E7:E7000))

 

HTH. Beste hilsen Harald

[geror]

Hei igjen

 

Jeg tror det må bli sånn:

 

=SUMMERPRODUKT((E7:E7000<IDAG())*(E7:E7000>0)*(F7:F7000<1))+SUMMERPRODUKT((E7:E7000<IDAG())*(E7:E7000>0)*(F7:F7000>E7:E7000))

 

HTH. Beste hilsen Harald

 

Helt supert! Tusen takk for hjelpen. Det gjorde susen =)